《二、单行代码拆分多行》
1、用下划线 “_” 在一行代码中的空处进行拆分
2、注：下划线前面最好加个空格，还有下划线后面不能有任何字符（包括空格）
============【代码】===========
// 拆分字符串
字符串 = _
" 作者：神梦无痕" & _
" QQ：1042207232" & _
" Q群：584781753"
TracePrint 字符串
// 拆分数组
数组 = Array( _
"a", _
"b", _
"c" _
)
// 拆分API声明
Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" ( _
ByVal lpClassName As String, _
ByVal lpWindowName As String _
) As Long
TracePrint FindWindow(vbNullString, "按键精灵")
// 拆分If语句
If 条件A = True _
And 条件B = True _
Or 条件C = False Then
TracePrint "成功！"
End If
==============================

《三、表示八进制和十六进制数》
1、用 “&O” 前缀表示八进制数，返回的是一个十进制数
2、注：“O” 是字母，不是数字零
============【代码】===========
// 可以用大写
整数 = &O11
TracePrint 整数
// 可以用小写
整数 = &o11
TracePrint 整数
// 在 &O100000 ~ &O177777 范围会返回负数
// 需要在尾部加 & 符号
负数 = &O100000
正数 = &O100000&
TracePrint 负数
TracePrint 正数
// &O 与变量结合使用
变量 = "177777"
整数 = CLng("&O" & 变量)
TracePrint 整数
// 十进制转八进制
八进制 = Oct(1024)
TracePrint 八进制
==============================
3、用 “&H” 前缀表示十六进制数，返回的是一个整数
4、注：十六进制只能用 0~9、A~F 表示
============【代码】===========
// 可以用大写
粉色 = &HFF00FF
TracePrint 粉色
// 可以用小写
绿色 = &hff00ff
TracePrint 绿色
// 在 &H8000 ~ &HFFFF 范围会返回负数
// 需要在尾部加 & 符号
负数 = &H8000
正数 = &H8000&
TracePrint 负数
TracePrint 正数
// &H 与变量结合使用
变量 = "800080"
紫色 = CLng("&H" & 变量)
TracePrint 紫色
==============================

《四、直接表示日期时间的符号》
1、用 “#” 来表示日期时间类型
============【代码】===========
// 日期用斜杠分割
日期时间 = #2022/11/06 22:04:00#
TracePrint TypeName(日期时间)
// 日期用横杠分割
日期时间 = #2022-11-06 22:04:00#
TracePrint TypeName(日期时间)
// 只显示日期
日期时间 = #2022-11-06#
TracePrint TypeName(日期时间)
// 只显示时间
日期时间 = #22:04:00#
TracePrint TypeName(日期时间)
// 判断日期时间
If Now() > #2022-11-06 22:04:00# Then
TracePrint "时间过期了！"
End If
// 只判断时间
If #06:00:00# <= Time() And Time() < #12:00:00# Then
TracePrint "上午"
ElseIf #12:00:00# <= Time() And Time() < #18:00:00# Then
TracePrint "下午"
Else
TracePrint "晚上"
End If
==============================

《五、中括号的特殊用法》
1、在 “VBSBegin ... VBSEnd” 块中无法使用中文作为变量
2、需要用中括号 “[]” 进行包裹，否则报错
============【代码】===========
// 包裹中文变量
VBSBegin
[中文变量] = "神梦无痕"
TracePrint [中文变量]
VBSEnd
// 当对象某个属性名和按键精灵关键字冲突，
// 也需要用中括号 `[]` 进行包裹，否则报错
Set re = New RegExp
re.Pattern = "\d+" '匹配所有数字
re.[Global] = True
Set Matches = re.Execute("QQ：1042207232；Q群：584781753")
For Each Match in Matches ' Iterate Matches collection.
匹配结果 = 匹配结果 & Match.Value & "|"
Next
TracePrint 匹配结果
==============================

《六、字符串中的双引号》
1、按键精灵中的字符串是用双引号括起来的
2、如果字符串内部有双引号怎么办呢？
============【代码】===========
// 直接用两个双引号转义表示
字符串 = "{""作者"":""神梦无痕"", ""QQ"":1042207232}"
TracePrint 字符串
// 用 Chr(34) 表示
引号 = Chr(34)
字符串 = 引号 & 引号 & 引号 & "三个双引号中的内容" & 引号 & 引号 & 引号
TracePrint 字符串
==============================

《七、字符串中的换行符》
1、让按键精灵中的字符串显示换行效果
============【代码】===========
// 直接用 vbCrLf 表示换行符
字符串 = _
"第1行、作者：神梦无痕" & vbCrLf & _
"第2行、QQ：1042207232" & vbCrLf & _
"第3行、Q群：58478175" & vbCrLf
MessageBox 字符串
// 用 Chr(13) & Chr(10) 表示
换行符 = Chr(13) & Chr(10)
字符串 = _
"第1行、作者：神梦无痕" & 换行符 & _
"第2行、QQ：1042207232" & 换行符 & _
"第3行、Q群：58478175" & 换行符
MessageBox 字符串
==============================

《八、Select Case 也支持条件判断》
1、让 Case 分支用表达式判断
============【代码】===========
输入 = 1
Select Case True
Case 输入 < 0
TracePrint "小于零"
Case 输入 > 0
TracePrint "大于零"
Case Else
TracePrint "等于零"
End Select
==============================

《按键论坛原帖》
http://bbs.anjian.com/showtopic-703086-1.aspx